外中断
1. 外中断
CPU 在计算机系统中,除了能够执行指令,进行运算以外,还应该能够对外部设备进行控制,接收它们的输入,向它们进行输出(I/O 能力)
PC 系统的接口卡和主板上,装有各种接口芯片。这些外设接口芯片的内部有若干寄存器,CPU 将这些寄存器当作端口来访问
外设的输入不直接送入内存和 CPU,而是送入相关的接口芯片的端口中； CPU 向外设的输出也不是直接送入外设,而是先送入端口中,再由相关的芯片送到外设。 CPU 还可以向外设输出控制命令,而这些控制命令也是先送到相关芯片的端口中,然后再由相关的芯片根据命令对外设实施控制。
即：CPU 通过端口和外部设备进行联系
当 CPU 外部有需要处理的事情发生的时候,比如说,外设的输入到达,相关芯片将向 CPU 发出相应的中断信息。CPU 在执行完当前指令后,可以检测到发送过来的中断信息,引发中断过程,处理外设的输入。
2. PC 系统中,外中断源有两类
1、可屏蔽中断
可屏蔽中断是 CPU 可以不响应的外中断。CPU 是否响应可屏蔽中断,要看标志寄存器的 IF 位的设置。 当 CPU 检测到可屏蔽中断信息时,如果 IF=1,则 CPU 在执行完当前指令后响应中断,引发中断过程；如果 IF=0,则不响应可屏蔽中断。
可屏蔽中断信息来自于 CPU 外部,中断类型码是通过数据总线送入 CPU 的；而内中断的中断类型码是在 CPU 内部产生的。
中断过程中将 IF 置 0 的原因就是,在进入中断处理程序后,禁止其他的可屏蔽中断。 如果在中断处理程序中需要处理可屏蔽中断,可以用指令将 IF 置 1。
8086CPU 提供的设置 IF 的指令：sti,设置 IF=1；cli,设置 IF=0。
2、不可屏蔽中断
不可屏蔽中断是 CPU 必须响应的外中断。当 CPU 检测到不可屏蔽中断信息时,则在执行完当前指令后,立即响应,引发中断过程。
对于 8086CPU,不可屏蔽中断的中断类型码固定为 2,所以中断过程中,不需要取中断类型码。则不可屏蔽中断的中断过程为： ① 标志寄存器入栈,IF=0,TF=0； ②CS、IP 入栈； ③(IP)=(8),(CS)=(0AH)。
几乎所有由外设引发的外中断,都是可屏蔽中断。当外设有需要处理的事件(比如说键盘输入)发生时,相关芯片向 CPU 发出可屏蔽中断信息。不可屏蔽中断是在系统中有必须处理的紧急情况发生时用来通知 CPU 的中断信息。
3. PC 机键盘的处理过程
键盘中有一个芯片对键盘上的每一个键的开关状态进行扫描。按下一个键时,开关接通,该芯片就产生一个扫描码,扫描码说明了按下的键在键盘上的位置。扫描码被送入主板上的相关接口芯片的寄存器中,该寄存器的端口地址为 60h。 松开按下的键时,也产生一个扫描码,扫描码说明了松开的键在键盘上的位置。松开按键时产生的扫描码也被送入 60h 端口中。
一般将按下一个键时产生的扫描码称为通码,松开一个键产生的扫描码称为断码。
扫描码长度为一个字节,通码的第 7 位为 0,断码的第 7 位为 1 即：断码 = 通码 + 80h。比如,g 键的通码为 22h,断码为 a2h
键盘的输入到达 60h 端口时,相关的芯片就会向 CPU 发出中断类型码为 9 的可屏蔽中断信息。CPU 检测到该中断信息后,如果 IF=1,则响应中断,引发中断过程,转去执行 int 9 中断例程。
BIOS 提供了 int 9 中断例程,用来进行基本的键盘输入处理,主要的工作如下：
- 读出 60h 端口中的扫描码；
- 如果是字符键的扫描码,将该扫描码和它所对应的字符码(即 ASCII 码)送入内存中的 BIOS 键盘缓冲区(15 个字型数据)；
- 如果是控制键(比如 Ctrl)和切换键(比如 CapsLock)的扫描码,则将其转变为状态字节写入内存中存储状态字节的单元(0040:0017)；
- 对键盘系统进行相关的控制,比如说,向相关芯片发出应答信息。
BIOS 键盘缓冲区可以存储 15 个键盘输入,一个键盘输入用一个字单元存放,高位字节存放扫描码,低位字节存放字符码(ASCII)。
如果 60h 端口获取的扫描码为字符键,则将扫描码和对应的 ASCII 码放到 BIOS 的键盘缓冲区(15 个字型数据),
CPU 对外设输入的通常处理方法 (1)外设的输入送入端口； (2)向 CPU 发出外中断(可屏蔽中断)信息； (3)CPU 检测到可屏蔽中断信息,如果 IF=1,CPU 在执行完当前指令后响应中断,执行相应的中断例程； (4)可在中断例程中实现对外设输入的处理。
4. 编程:在屏幕中间依次显示 'a' ~ 'z',并可以让人看清。在显示的过程中,按下 ESC 键后,改变显示的颜色
; 编程:在屏幕中间依次显示 'a' ~ 'z',并可以让人看清。在显示的过程中,按下ESC键后,改变显示的颜色。
; ====================================================
assume cs:codesg, ds:datasg, ss:stacksg
; ====================================================
stacksg segment stack
db 128 dup (0)
stacksg ends
; ====================================================
datasg segment
dw 0, 0
datasg ends
; ====================================================
codesg segment
start: mov ax, stacksg
mov ss, ax
mov sp, 128
call save_init_int9
call loop_show
call recover_int9
mov ax, 4c00h
int 21H
; ------------------------------------------
; 循环打印
loop_show:
push ax
push es
mov ax, 0B800H
mov es, ax
mov ah, 'a'
_loopShow:
mov es:[160 * 12 + 40 * 2], ah
call sleep
inc ah
cmp ah, 'z'
jna _loopShow
pop es
pop ax
ret
; ------------------------------------------
; 将 datasg 段中原来的 int9 的地址恢复
recover_int9:
push ax
push ds
push es
mov ax, datasg
mov ds, ax
mov ax, 0
mov es, ax
push ds:[0]
pop es:[4 * 9 + 0]
push ds:[2]
pop es:[4 * 9 + 2]
pop es
pop ds
pop ax
ret
; ------------------------------------------
; 将原来的 int9 的地址保存到 datasg 段中,并设置新的int9
save_init_int9:
push ax
push ds
push es
mov ax, datasg
mov ds, ax
mov ax, 0
mov es, ax
push es:[9 * 4 + 0] ; IP
pop ds:[0]
push es:[9 * 4 + 2] ; CS
pop ds:[2]
cli ; 防止在设置CS:IP时中断,防止只设置一半
mov word ptr es:[9 * 4 + 0], OFFSET new_int9
mov es:[9 * 4 + 2], cs
sti
pop es
pop ds
pop ax
ret
; ------------------------------------------
; 新的int9
new_int9: push ax
push bx
push ds
push es
mov ax, datasg
mov ds, ax
in al ,60H
pushf
; pushf
; pop bx
; and bh, 11111100B
; push bx
; popf ; IF = 0, TF = 0
call dword ptr ds:[0] ; 对int指令进行模拟,调用原来的int9中断例程
cmp al, 1
jne _retNewInt9
mov ax, 0B800H
mov es, ax
inc byte ptr es:[160 * 12 + 40 * 2 + 1]
_retNewInt9:
pop es
pop ds
pop bx
pop ax
iret ; 注意是 ret
; ------------------------------------------
; 延时显示
sleep:
push ax
push dx
mov dx, 10
mov ax ,0
_sleep:
sub ax, 1
sbb dx, 0
cmp ax, 0
jne _sleep
cmp dx, 0
jne _sleep
pop dx
pop ax
ret
codesg ends
end start